home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 090 / yase.arc / EXEC.ASM < prev    next >
Encoding:
Assembly Source File  |  1986-12-13  |  4.6 KB  |  133 lines
  1. ******************************************************************
  2. * COPYRIGHT (C) 1986 by Donald Krantz and James Stanley
  3. * - Note: This is a real, live, actual, registered copyright,
  4. *   and should be treated as such. This source code is from
  5. *   the book "68000 Assembly Language", Krantz and Stanley,
  6. *   Addison-Wesley Publishing Company, Reading, MA, 1986.
  7. * 
  8. *   Permission granted by the authors for non-commercial use
  9. *   in programs released to the public domain, as long as this
  10. *   copyright notice remains attached and visible.
  11. *
  12. ****************************************************************
  13. * EXEC - Editor Executive Routine & Globals
  14. * Contains main editor loop and universal variables.
  15.  
  16.     xref    g_3,readfile,refresh,set_edit,open_w,cls,cmd_w
  17.     xref    filenm,edit,border_w,set_w
  18.     xdef    query,findpat,reppat,repflag,exec,p_buf,p_cnt
  19.     xdef    used,get_buf
  20.  
  21. #edit.h
  22. #cursor.h
  23.  
  24. BUFS    equ    5        * Max number of open windows
  25.  
  26. *****************************************************************
  27. exec:
  28.     bsr    init        * Initialze local vars
  29.     bsr    cls        * Initialize virtual screen
  30.     move.l    #cmd_w,(a5)    * open command I/O window
  31.     bsr    border_w    * 
  32.     bsr    get_buf        * open buffer
  33. lpx:
  34.     bsr    edit        * do editing
  35.     tst.w    d0        * look at return code
  36.     beq    skx        * non-zero means window commands
  37.     bsr    g_3        * go do window commands
  38.     bra    lpx        * resume edit
  39. * Dump current window
  40. skx:
  41.     move.l    free,a0        * save free list link
  42.     move.l    a5,free        * put current window in free list
  43.     move.l    (a5),a1        * get link to next item in chain
  44.     move.l    a1,used        * put used list back together
  45.     move.l    a0,(a5)        * link to free link
  46. * Relink and Redraw
  47.     tst.l    used        * get top used window pointer
  48.     beq    ed_exit        * quit if no more windows
  49.     bsr    refresh        * redraw the screen
  50.     bra    lpx
  51. ed_exit:
  52.     bsr    cls        * leave screen pretty
  53.     rts            * this is editor exit
  54. *****************************************************************
  55. * GET_BUF - finds and opens the next available window
  56. get_buf:
  57.     tst.l    free        * check for buffer in free list
  58.     beq    no_buf        * jump on no buffer
  59.     move.l    free,a5        * get next free buffer
  60.     move.l    (a5),free    * replace free list link
  61.     move.l    used,(a5)    * link used link
  62.     move.l    a5,used        * replace used list link
  63.     cmp.l    #end_d,defs    * see if we overran defaults
  64.     blt    sk0_gb        * jump if not
  65.     move.l    #s_def,defs    * reset defaults
  66. sk0_gb:
  67.     move.l    defs,a3        * Get default size window address
  68.     addq.l    #8,defs        * move pointer for next time
  69.     move.w    (a3)+,d0    * Get default upper left X
  70.     move.w    (a3)+,d1    * Get default upper left Y
  71.     move.w    (a3)+,d2    * Get default lower right X
  72.     move.w    (a3)+,d3    * Get default lower right Y
  73.     bsr    set_w        * Setup window parameters
  74.     bsr    set_edit    * Setup editor parameters
  75.     bsr    readfile    * Get filename and file
  76.     move.l    #filenm,a0    * Save name of file locally
  77.     lea    fname(a5),a1    * A1 is address where name goes
  78. lp:
  79.     move.b    (a0)+,(a1)+    * We just transfer bytes until
  80.     bne    lp        *  we find a null
  81.     bsr    open_w        * Open the window
  82.     rts
  83. no_buf:
  84. * set correct edit error and return
  85.     rts
  86. *****************************************************************
  87. * INIT - Initializes local variables
  88. init:
  89.     move.l    #cmd_w,a5    * Open command I/O window
  90.     move.w    #0,d0        * set command window limits
  91.     move.w    #0,d1
  92.     move.w    #79,d2
  93.     move.w    #3,d3
  94.     bsr    set_w        * init command window
  95.     clr.b    filenm        * zero out current filename 
  96.     clr.l    used        * Zap the in-use buffer pointer
  97.     move.w    #BUFS-1,d0    * Buffer count
  98.     move.l    #win,a1        * Start the linked list 
  99.     move.l    a1,free        * get the first pointer
  100. lp0_li:
  101.     move.l    a1,a0        * moves pointer up one node
  102.     add.l    #DESC,a1    * calcs address of next buffer
  103.     move.l    a1,(a0)        * loads address of next buffer
  104.     dbra    d0,lp0_li    * loop for BUFS times
  105.     clr.l    (a0)        * mark last buffer as end of list
  106.     move.l    #defaults,defs    * setup default window frame
  107.     rts
  108. *****************************************************************
  109. * Default window corners.
  110. defaults:
  111.     dc.w    lim_lx,lim_uy,lim_rx,lim_ly    * window 1
  112. s_def:
  113.     dc.w    1,5,75,15    * Default size of window 2n
  114.     dc.w    2,7,76,17    * Default size of window 3n
  115.     dc.w    3,10,77,20    * Default size of window 4n
  116.     dc.w    4,12,78,22    * Default size of window 5n
  117. end_d    equ    *
  118. *****************************************************************
  119.     bss
  120. query:    ds.b    80        * g.p. query buffer
  121. findpat:ds.b    80        * find string pattern
  122. reppat:    ds.b    80        * replace string buffer
  123. repflag:ds.w    1        * "replace" request flag
  124. defs    ds.l    1        * current frame default
  125. free:    ds.l    1        * free buffer linked list ptr
  126. used:    ds.l    1        * in-use buffer link pointer
  127. win:    ds.b    DESC*BUFS    * editing buffers & pointers
  128. e_win    equ    *        * end of windows
  129. p_cnt:    ds.w    1        * Char count in paste buffer
  130. p_buf:    ds.b    $10000        * 64K paste buffer
  131.  
  132.     end
  133.